Решил вот свои пять копеек вставить чтобы тему поднять выше
Простейший вариант рекурсивной обработки. Можно будет использовать как основу для других скриптов, требующих рекурсии. Скрипт не использует объект TCScript.
Скрипт удаляет пустые папки внутри текущей директории и во всех вложенных в нее. А если текущая будет корневой - во всем диске тогда. В параметрах кнопки для этого скрипта поставьте %P
======= DelEmtySubDirs.vbs =======
' ©2004, Volniy
Option Explicit
Dim fso
Dim StartFolder
Dim objArgs
Set objArgs = WScript.Arguments
Set fso = CreateObject("Scripting.FileSystemObject")
If objArgs.Count = 1 Then
' Текущая директория, получаем через %P в командной строке
StartFolder = objArgs(0)
Else
MsgBox "Должен быть один параметр!", vbCritical
WScript.Quit
End If
'Можно указать начальную папку и напрямую
'StartFolder = "D:\"
If fso.FolderExists(StartFolder) = False Then
MsgBox "Неверная директория!", vbCritical
WScript.Quit
End If
ScanFolder StartFolder
MsgBox "Пустые папки в '" & StartFolder & "' удалены!", vbInformation
Set fso = Nothing
Set objArgs = Nothing
WScript.Quit
Sub ScanFolder(FolderPath)
Dim curFolder
Dim FItem
Set curFolder = fso.GetFolder(FolderPath)
For Each FItem In curFolder.SubFolders
ScanFolder FItem.Path
Next
' Проверка на условие для удаления
If curFolder.SubFolders.Count = 0 And curFolder.Files.Count = 0 Then
curFolder.Delete
End If
Set curFolder =Nothing
End Sub
======= DelEmtySubDirs.vbs =======
PS Хоть бы кто мне раньше сказал, что есть такая штуковина как Total Commander Script Editor, я бы ни в жисть не назвал свою байду TCScript. Это ж надо было так народ запутать
Следующую версию переименую...